Procedura FREQ-in SAS

Proceduri SAS

-Procedura FREQ;

-Teste statistice cu procedura FREQ.

Procedura FREQ

Exemplul 1. Crearea unor tabele de frecvenţă

data Color;

input Regiune Ochi $ Par $ Numar @@;

label Ochi ='Culoarea ochilor'

Par ='Culoarea parului'

Regiune='Regiune geografica';

datalines;

1 albastri blond 23 1 albastri roscat 7 1 albastri saten 24

1 albastri negru 11 1 verzi blond 19 1 verzi roscat 7

1 verzi saten 18 1 verzi negru 14 1 caprui blond 34

1 caprui roscat 5 1 caprui saten 41 1 caprui negru 40

1 caprui negru 3 2 albastri blond 46 2 albastri roscat 21

2 albastri saten 44 2 albastri negru 40 2 albastri negru 6

2 verzi blond 50 2 verzi roscat 31 2 verzi saten 37

2 verzi negru 23 2 caprui blond 56 2 caprui roscat 42

2 caprui saten 53 2 caprui negru 54 2 caprui negru 13

;

proc freq data=Color;

weight Numar;

tables Ochi Par Ochi*Par / out=FreqCnt outexpect sparse;

title1 'Culoarea ochilor si a parului la copiii europeni’;

run;

proc print data=FreqCnt noobs;

title2 'Output';

run;

În acest exemplu:

- Se creează tabelul de date Color, conţinând informaţii referitoare la culoarea ochilor şi a părului pentru copii europeni provenind din două regiuni geografice.Tabelul are 4 variabile: regiune (regiunea geografica), Ochi (Culoarea ochilor), Par (culoarea parului), Numar (Numărul de copii având cracteristicile respective);

- Tabelul este populat cu 27 de observaţii;

- procedura FREQ este folosită cu următoarele clauze:

-WEIGHT – specifică o variabilă numerică (aici Numar), ce indică frecvenţa observaţiei; folosirea clauzei indică faptul că o singură observaţie indică de fapt n observaţii, unde n este valoarea variabilei specificate în clauză. Aici, valoarea variabilei Numar reprezintă numărul (ponderea) copiilor având anumite caracteristici fizice;

-TABLES – indică tabelele de frecvenţă ce vor fi create, în cazul acesta 3 tabele: frecvenţa pentru culoarea ochilor, frecvenţa pentru culoarea părului şi tabelul încrucişat (crosstabulation) culoare ochi - culoare păr;

Opţiunile clauzei TABLES:

- OUT – creează tabelul de date FreqCnt, conţinând tabelul de frecevnţă încrucişat;

- SPARSE – listază toate combinaţiile posibile ale celor două variabile din tabelul de frecvenţă încrucişat.

- procedura PRINT afişează conţinutul tabelului FreqCnt.

Exemplul 2. Testul statistic chi-pătrat pentru un tabel de frecvenţă

Acest exemplu verifică ipoteza conform căreia culoarea părului la copiii europeni (vezi exemplul anterior) are o distribuţie multinomială: 30% blond, 12% roşcat, 30% şaten, 28% negru.

proc sort data=Color;

by Regiune;

run;

proc freq data=Color order=data;

weight Numar;

tables Par / nocum testp=(30 12 30 28);

by Regiune;

title 'Culoarea parului la copiii europeni';

run.